Vlookup函數(shù)的教程網(wǎng)上已非常多了，而貼近工作用的Vlookup函數(shù)應(yīng)用示例卻很少。今天給大家?guī)硪黄赩lookup函數(shù)示例大全，希望能給大家的工作帶來幫助。

【例1】查找個人信息

=VLOOKUP($B18,$C$7:$H$15,COLUMN(B1),0)

注：Colum(b1)的結(jié)果是2，當(dāng)公式向右復(fù)制時可以生成3，4，5，..

【例2】合并兩個表格

F2單元格公式

=VLOOKUP(B2,$B$14:$F$22,MATCH(F$1,$B$13:$F$13,0))

公式說明：用Match函數(shù)查找表1的標(biāo)題在表2中的位置

【例3】讓兩個表格同類商品排序完全一樣

F2單元格公式

=IFERROR(VLOOKUP($B2,$B$12:$D$16,COLUMN(A1),),"")

公式說明：IFERROR函數(shù)用來屏蔽錯誤值

【例4】制作工資條

=VLOOKUP($G96,$A$96:$E$104,COLUMN(B1),)

公式說明：根據(jù)序號從工資表中查找對應(yīng)的信息

【例5】計算個人所得稅

=(G28-3500)*VLOOKUP(G28-3500,C28:E34,2)-VLOOKUP(G28-3500,C28:E34,3)

公式說明：當(dāng)Vlookup最后一個參數(shù)為1或省略時，查找為近似匹配。即查找比指定值小且最接近的值。

【例6】模糊查找產(chǎn)品名稱（包含查找）

=VLOOKUP("*"&F41&"*",$B$41:$D$47,3,0)

注：*是通配符，代表任意多個字符

【例7】帶特殊符合的字符查找

=VLOOKUP(SUBSTITUTE(F52,"~","~~"),B$52:C$56,2,0)

注：由于~ * ？在公式中有通配符用法，遇到被查找的字符串中含有這3個字符就用Substitute替換為~~、~*和~？

【例8】逆向查找

=VLOOKUP(G61,IF({1,0},C61:C69,B61:B69),2,)

公式說明: 本公式只做了解，遇到逆向查找，建議使用Index+Match函數(shù)。

=INDEX(B60:B69,MATCH(G61,C60:C69,0))

【例9】16年與17年單價核對，表格核對（帶通配符），結(jié)果顯示多N 或 少N

=TEXT(VLOOKUP(SUBSTITUTE(B73,"*","~*"),$F$73:$G$92,2,)-C73,"少0.00;多0.00;")

公式說明:Text可以設(shè)置數(shù)字顯示的格式

【例10】Vlookup多條件查找

A112 =B112&C112

H112 =VLOOKUP(F112&G112,A112:D120,4,0)

公式說明：Vlookup也可以使用IF({1,0}的數(shù)組形式實(shí)現(xiàn)多條件查找，但運(yùn)行效率太慢，所以建議使用輔助列連接再查找的方法。

【例11】庫存單價的監(jiān)控。銷售單價>庫存單價時填充紅色背景

設(shè)置方法：選取區(qū)域 - 條件格式 - 新建規(guī)則 - 使用公式確定... - 在下面框中輸入公式：

=H2>VLOOKUP(F2,A:C,3,0)

最后點(diǎn)“格式”按鈕設(shè)置填充色為紅色

【例12】銀行存款最近30天到期提醒。表中要有某天匯總金額，也要有明細(xì)金額。

設(shè)置方法：

步驟1 添加輔助列，根據(jù)到期日生成 到期日+序列（目的是對同一個日期編序號，方便Vlookup一對多查找）

=D2&"-"&COUNTIF(D$2:D2,D2)

步驟2 設(shè)置到期日公式，H2單元格輸入=Today() ,H3=H2+1,然后H3公式向下復(fù)制

步驟3 設(shè)置求和公式，用來統(tǒng)計每個到期時需要還款的總金額

=SUMIF(D:D,H2,C:C)

步驟4 用Vlookup查找各行明細(xì)數(shù)據(jù)

J2單元格公式

=IFERROR(VLOOKUP($H2&"-"&J$1,$A:$D,2,0)&":"&VLOOKUP($H2&"-"&J$1,$A:$D,3,0),"")

公式說明： 這里把H列日期&第1行的數(shù)字作為查找內(nèi)容，在A列中進(jìn)行查找，然后返回 B列 & C列的數(shù)據(jù)，

財務(wù)人員日常接觸大量來自不同部門的高度細(xì)分的數(shù)據(jù)，這些數(shù)據(jù)有著各種各樣的格式。如果Excel不夠精通，對這些龐雜的數(shù)據(jù)進(jìn)行匯總、聯(lián)結(jié)、對比和分析將是一個非常耗時的過程。提取、轉(zhuǎn)換和計算過程中的每一個步驟都涉及到excel的使用技巧。這也是為什么財務(wù)精英都是Excel控的原因。

對財會人員來說，掌握Excel技巧可以讓工作更加省時省力，想要學(xué)習(xí)更多的excel技巧，來加入正保會計網(wǎng)校胡雪飛老師的《職場精英必備的EXCEL技巧》吧~~帶你掌握財務(wù)人員必會的數(shù)據(jù)整理、數(shù)據(jù)分析、報告撰寫技巧。點(diǎn)擊進(jìn)入>>

學(xué)習(xí)更多財稅資訊、財經(jīng)法規(guī)、專家問答、能力測評、免費(fèi)直播，可以查看正保會計網(wǎng)校會計實(shí)務(wù)頻道，點(diǎn)擊進(jìn)入>>。